Syntax
=TODAY()
(none)- TODAY has no arguments. Type the empty brackets anyway.
TODAY function in Google Sheets
TODAY returns today's date and updates by itself every day. Use it for anything that depends on "now": days until a deadline, overdue flags, ages and how long ago something happened. It takes no arguments, but the brackets are still required: =TODAY().
Practice TODAY
Task 1 of 4
How many days are left until each deadline? Work it out for the first task in C2. It should update every day.
Tip: while typing a formula, click a cell or drag across cells to insert references. Press Enter to check, and Tab to accept a function suggestion.
TODAY examples
Each example below runs against this sample sheet. The results are calculated by the same engine as the practice grid.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Task | Start | Due | Holidays |
| 2 | Kickoff | 1/5/2026 | 1/9/2026 | 1/19/2026 |
| 3 | Design | 1/12/2026 | 2/13/2026 | 2/16/2026 |
| 4 | Build | 2/16/2026 | 4/30/2026 | 5/25/2026 |
| 5 | Launch | 5/4/2026 | 5/29/2026 |
| Formula | Result | What it shows |
|---|---|---|
=TODAY() | Today's date | Today's date. |
=C3-TODAY() | Depends on today | Days until the Design task is due (negative once it has passed). |
=IF(C2<TODAY(), "Overdue", "") | Depends on today | A status that switches by itself. |
=TODAY()+30 | Depends on today | The date 30 days from now. |
=COUNTIF(C2:C5, "<"&TODAY()) | Depends on today | How many tasks are past their due date. |
=DATEDIF(B2, TODAY(), "M") | Depends on today | Whole months since the Kickoff started. |
Freezing today's date
TODAY changes every day, so it's the wrong tool for recording when something happened, such as the date an order arrived. To stamp a fixed date, press Ctrl+; (⌘+; on a Mac) in the cell. That types today's date as a plain value that never changes.
TODAY vs NOW
TODAY is the date only (a whole number). NOW also includes the time of day. Comparing a date column with NOW() can give surprising results, because a due date of today is already "less than" NOW once the morning has started. For date-only comparisons, use TODAY.
Tips and common mistakes
- In a criteria string, join TODAY with &: COUNTIF(C2:C5, "<"&TODAY()). Writing "<TODAY()" in quotes is compared as literal text and matches nothing.
- TODAY uses the spreadsheet's time zone (File › Settings), which may differ from your computer's.
- If a result shows as a number like 46100 instead of a date, apply a date format with Format › Number › Date.
Related functions
Learning step by step? TODAY is covered in Lesson 40: TODAY, NOW & DATEDIF of the free course.